Peter Moelgaard's Blog

Some time ago I was in need of something to be run at regular intervals.
Among the many implementations I already had in my framework, I thought that including either my Workflow package (An ActionScript port of the Windows Workflow Foundation 3) or my processing package (eventually just a scheduling application block which allows processes to be managed Windows Service style.

I wanted something much more lightweight, so I decided to implement a Schedule Handler.
It extends the AbstractHandlers class, so all I had to do was initiate a timer and then run the sequence when the timer elapsed… more lightweight then that is hard to imagine.

package org.hellogroup.mate.actionLists
{
	import com.asfusion.mate.actionLists.AbstractHandlers;
	import com.asfusion.mate.actionLists.Scope;

	import flash.events.TimerEvent;
	import flash.utils.Timer;

	public class Schedule extends AbstractHandlers
	{
		private var timer:Timer = null;

		public function Schedule()
		{
			super();

			this.timer = new Timer( 1000 );
			this.timer.addEventListener( TimerEvent.TIMER, this.handleTimer );
		}

		[Bindable]
		public function get delay() : Number
		{
			return timer.delay;
		}

		public function set delay( value:Number ) : void
		{
			this.timer.delay = value;
		}

		override public function initialized( document:Object, id:String ) : void
		{
			super.initialized( document, id );

			this.timer.start();
		}

		private function handleTimer( event:TimerEvent ) : void
		{
			this.runSequence( new Scope( event, true, this.map ), this.actions );
		}
	}
}

The class is included in the downloads in my previous post…
http://blog.petermolgaard.com/2009/05/30/mate-stopanddispatchhandlers-extension/

Some time ago I found myself in need of a couple of features not included in Mate, such as a StopHandler which would be interruptable, but instead of just returning from the entire ActionList, would dispatch an event which could be handled by another handler.

It was named StopAndDispatchHandlers and extends the standard StopHandlers.

First I created a somewhat abstract stophandlers class which overrides the run function and handles some of the more intricate details relating to the lastReturnEquals and lastReturn members of the scope object.

package org.hellogroup.mate.actions
{
	import com.asfusion.mate.actionLists.IScope;
	import com.asfusion.mate.actions.StopHandlers;

	public class StopHandlers extends com.asfusion.mate.actions.StopHandlers
	{
		public function StopHandlers()
		{
			super();
		}

		override protected function run( scope:IScope ):void
		{
			super.run( scope );

			if( lastReturnEquals == null && scope.lastReturn == null )
			{
				scope.stopRunning();
			}
		}
	}
}

Here is the concrete implementation which allows for a stophandler to dispatch an event.

package org.hellogroup.mate.actions
{
	import com.asfusion.mate.actionLists.IScope;
	import org.hellogroup.mate.actions.StopHandlers;
	import flash.events.Event;

	public class StopAndDispatchHandlers extends StopHandlers
	{
		private var _nextEvent:Event = null;

		public function StopAndDispatchHandlers()
		{
			super();
		}

		public function get nextEvent() : Event
		{
			return _nextEvent;
		} 

		public function set nextEvent( value:Event ) : void
		{
			_nextEvent = value;
		}

		override protected function run( scope:IScope ):void
		{
			super.run( scope );

			scope.dispatcher.dispatchEvent( nextEvent );
		}
	}
}

You can download the compiled binary from here…
http://petermolgaard.com/projects/MateSchedule.swc.zip

…and the entire sourcecode as a Flex project from here…
http://petermolgaard.com/projects/MateSchedule.fxpl.zip